Mạch Khóa Số Điện Tử Mạch Đếm Sản Phẩm Mạch Đèn giao thông Ngã Tư Mạch Trái Tim Final Mạch Trái Tim Final Mạch Trái Tim I Love U

September 21, 2012

Mạch đếm sản phẩm dùng Chip AT89C51


Mấy hôm nay Chip đang loay hoay tìm mạch đếm sản phẩm,để lắp 1 mạch đếm người qua lại,lang thang 1 hồi chip tìm được 1 bài viết rất hay và dễ hiểu lại Viết bằng ASM,đúng món chip cần,Chip lại đang học LT C rồi sẽ chuyển sang C cho anh em xem.Anh em điện tử có gì thắc mắc Comment bên dưới nhé?
                                
Đây là một mạch đếm sản phẩm ứng dụng vi điều khiển mcs_51 dùng thu phát hồng ngoại, tăng số lượng sản phẩm lên bằng kỷ thuật đếm xung, sử dụng phương pháp quét led để hiển thị số đếm và có khả năng dừng băng truyền

Bây giờ chúng ta bắt đầu nhé: Giới thiệu sơ qua cho các bác biết trong mạch có những gì nhé : để làm mạch này thì chúng ta có 3 khối chính đó là khối phát hồng ngoại , khối thu hồng ngoại, khối hiển thị và dĩ nhiên là không thể thiếu bộ xử lý trung tâm rồi đúng không, các bác dùng vi điều khiển họ 8051 nhé (ở đây mình dùng con 89c51)

Khối phát hồng ngoại: dùng timer0 để phát xung 38khz ở một chân của 89c51 ở đây mình chọn chân p1.5, còn vấn đề phát như thế nào thì mình sẻ nói sau.

Còn đây là sơ đồ mạch phát:
                                                      


ở đây mình dùng cách ghép darlington để khuếch đại tín hiệu đưa ra từ chân p1.5 vì tín hiệu từ 89c51 rất bé nên chúng ta cần khuếch đại dòng cho nó để đủ sáng led, Q1,Q2 các bác dùng loại NPN nhé ở đây mình dùng con C1815. Nói sơ qua cho các bác hiểu nguyên lý hoạt động của nó nhé: chúng ta phát dạng xung vuông có tần số là 38khz tức là chân p1.5 của 89c51 sẻ liên tục đảo chiều cứ lên 1 rồi lại xuống 0, khi p1.5 lên 1 thì Q1 dẫn lúc đó có dòng Vcc chạy từ cực C xuống E của Q1, vì cực E của Q1 nối với cực B của Q2 nên khi Q1 dẫn thì cực B của Q2 có dòng nên Q2 cũng dẫn và có dòng chạy từ Vcc qua cực C và xuống E của Q2 rồi qua led phát hồng ngoại qua điện trở rồi xuống mass, lúc này led phát hồng ngoại sáng còn khi chân p1.5 xuống mức 0 thì Q1 và Q2 không dẫn nên led phát hồng ngoại tắt.

khối thu hồng ngoại : có chức năng là phát hiện sự mất xung ( có sản phẩm đi qua ) và đưa về con 89c51 để xử lý tăng số đếm lên 1 đơn vị

đây là sơ đồ mạch thu:

                                         

Các bác nối theo sơ đồ nhé, cho mấy bác thông số luôn nè: R15 là 2k2, R16 chọn 1K R16 có khả năng chống nhiểu nữa nếu như có nhiểu thì các bác chỉ việc thay con trở R16 có giá trị nhỏ hơn là được nhưng mà mình nghĩ chắc là không còn nhiểu đâu vì ngày xư mình dùng tới 22k và rất nhiểu nên giờ giảm xuống 1k và thấy rất tốt các bác yên tâm, R17 chọn 100Ω, biến trở R18 chọn 100k, tụ C4 và C5 chọn khoảng 10uF.

Nguyên lý hoạt động: khi có sản phẩm đi qua thì led thu hồng ngoại bị che khuất lúc này có dòng đi từ Vcc qua led thu hồng ngoại ròi qua cực B của Q3 lúc này Q3 dẫn, cực C của Q3 xuống mức thấp lúc này tụ C4 xả điện qua diode qua Q3 và xuống mass lúc này chân số 2 của LM555 được kích và tạo ra một xung ở chân số 3 đưa về cho ic89c51 xử lý. (chân số 3 của LM555 được nối vào chân P3.2 của 89c51 tức là chân 12 )

Biến trở R18 dùng để điều chỉnh tốc độ nhận dạng sản phẩm đi qua, khi có sản phẩm đi qua thì led thu hồng ngoại bị che khuất ta có sơ đồ mất xung như sau.


                                  
Khối hiển thị : dùng để hiển thị số lượng sản phẩm đã đi qua.

Đây là sơ đồ khối hiển thị:
                            


Q4 và Q5 dùng loại PNP ở đây mình dùng A1015. Còn R13, R14 thì các bác chọn khoảng 10k còn trở R5 đến R12 thì các bác chọn sao cho led đủ sáng nhé (nên chọn giá trị nhỏ thôi ) còn bác nào mà sợ tốn trở thì làm thế này bỏ R5 đến R12 đi ta cứ nối thẳng nó vào Port0 của 89c51 thay vào đó là ta sẻ gắn cho nó một con trở ở cực C của Q4 và Q5 là khoảng 220Ω các bác cứ chọn sao cho led đủ sáng là được. Ở đây mình dùng led Anot chung ( loại Anot chung này chân chung được nối lên nguồn )

Led 7đoạn các bác về giải mã nó nhé.

Đây là hình dạng của led



Các bác dùng VOM để ở thang đo điện trở nhỏ nhất rồi đưa que đỏ vào chân số 3 hoặc chân số 8 que còn lại lần lượt đưa vào các chân 1,2,4,5,6,7,9,10 xem đâu là a, đâu là b… ( lưu ý là VOM trên thị trường có loại của trung quốc thì que đỏ là cực âm và que đen là cực dương các bác chú ý nhé nếu là loại này thì phải làm ngược lại đưa que đen vào chân số 3 hoặc 8 còn que kia thì đo các chân còn lại )

Còn ở đây mình giải mã ra được : 1:e 2:d 3:Vcc 4:c 5:dp 6:b 7:a 8:Vcc 9:f 10:g

Các bác nối chân của led vào port0 như thế này nhé: “a” nối vào chân P0.7 ( tức là chân 32 của 89c51 ) lần lượt cho tới “dp” nối vào chân P0.0 (tức là chân 39 của 89c51) 
Như vậy là xong phần cứng bây giờ chúng ta thử cho nó hiển thị lên số 0 nhé. Quy tắc là như thế này khi ta cho phép dòng đi qua con led thì led tích cực và muốn cho chổ nào sáng thì ta cho chổ đó về 0 giả sử muốn cho led đơn vị sáng lên số 0 thì ta điều khiển sao cho chân p1.7 lên mức 1 và chân p1.6 về mức 0 như vậy là led đơn vị được cho phép và muốn hiển thị lên số 0 thì ta cần làm cho các thanh led a,b,c,d,e,f sáng để cho nó sáng thì các chân này sẻ về mức 0 (cụ thể như con led mình đã giải mã thì mình điều khiển con 89c51 để cho chân 1,2,4,6,7,9, của led về mức 0 vậy là sẻ có số 0 hiển thị trên led đơn vị ) như vậy thì muốn hiển thị số 0 thì P0 cần xuất ra giá trị là 00000011 tức là 03H tương tự số 1 là chân "b,c" sáng và port0 cần xuất ra giá trị là 10011111 tức là F9H tương tự ta có được bảng số như sau: 0 = 03H; 1 = 9FH; 2 = 25H; 3 = 0DH; 4 = 99H; 5 = 49H; 6 = 41H; 7 = 1FH; 8 = 01H ; 9 = 09H

Đây là mạch tổng quát :(click vào ảnh để phóng to)

                                           

Phần cứng như thế là ổn bây giờ chúng ta đi viết chương trình cho nó nhé:Để viết chương trình các bạn cần nắm được mình cần làm gì cái đã: chúng ta đang làm một mạch đếm sản phẩm và chúng ta quản lý số đếm trong R7 nên chương trình chính chúng ta có nhiệm vụ là nạp các giá trị ban đầu cho phép ngắt, tách số BCD và hiển thị ra LED. Trong mạch này chúng ta sử dụng 3 nguồn ngắt đó là ngắt timer0 dùng để phát xung cho mạch phát, ngắt ngoài 0 dùng để tăng số lượng sản phẩm và ngắt timer1 dùng để dừng băng truyền.Chương trình phát xung: sử dụng ngắt timer0 chế độ 2 ( timer0 chế độ 2 có khả năng tự nạp lại giá trị ban đầu nên chúng ta chỉ cần nạp một lần là đủ ). Chúng ta dùng thạch anh 12MHz nên ta có 1 chu kỳ máy = 1µs, chúng ta phát ở tần số 38khz vậy ta có T=1/f = 1/38 = 0.026ms = 26 µs → Ton =Toff = 26/2 = 13 
như vậy cần nạp cho timer0 giá trị là -13.Trong chương trình ngắt timer0 ta chỉ việc đảo trạng thái chân p1.5 là được và ta có đoạn chương trình ngắt timer0 là:





T0_ISR:
CPL P1.5
RETI




Chương trình đếm sản phẩm: chúng ta sử dụng ngắt ngoài 0. Khi phát hiện mất xung ( có sản phẩm đi qua) chân P3.2 xuống mức thấp và lúc này xảy ra ngắt ngoài 0. Trong chương trình ngắt ngoài 0 chúng ta tăng số đếm lên 1 đơn vị và so sánh nó với giá trị là 100 khi nó đạt đến 100 thì reset nó về 0
ta có đoạn chương trình ngắt ngoài 0:






EX0_ISR:
INC R7 ; tang s? d?m lên 1 don v?
CJNE R7,#100,EXIT ;so sánh R7 v?i 100 n?u chua = 100 thì nh?y t?i EXIT còn n?u b?ng 100 thì xóa nó v? 0
MOV R7,#0
EXIT: RETI




Còn bác nào muốn dừng băng truyền thì trong chương trình ngắt ngoài 0 ta so sánh số đếm với các giá trị định sẳn chẳng hạn như các giá trị 20,40,60,80,100, khi số đếm bằng các giá trị này thì cho dừng bằng truyền trong 5s rồi cho băng truyền hoạt động trở lại.
ta có lại đoạn chương trình ngắt ngoài 0 như sau:






E0_ISR:
INC R7 ; tăng R7 lên 1
CJNE R7,#20,TIEP ; so sánh R7 với 20, nếu chưa bằng thì nhảy tới nhản TIEP còn nếu bằng rồi thì gọi chương trình TIEPTUC
ACALL TIEPTUC ; gọi chương trình TIEPTUC
TIEP: CJNE R7,#40,TIEP1 ; so sánh R7 với 40
ACALL TIEPTUC ; gọi chương trình tiếp tục
TIEP1: CJNE R7,#60,TIEP2 ; so sánh R7 với 60
ACALL TIEPTUC ; gọi chương trình TIEPTUC
TIEP2: CJNE R7,#80,TIEP3 ; so sánh R7 với 80
ACALL TIEPTUC ; gọi chương trình TIEPTUC
TIEP3: CJNE R7,#100,EXIT ; so sánh R7 với 100
MOV R7,#0 ; xóa R7 về 0
ACALL TIEPTUC ; gọi chương trình TIEPTUC
EXIT: RETI ; quay về từ ngắt





Trong chương trình TIEPTUC chúng ta sẻ cho dừng băng truyền nhưng ở đây mình chỉ làm mô phỏng nên mình thay cái động cơ điều khiển băng truyền là một con led khi led sáng thì báo hiệu là đang dừng băng truyền.
Trong main chúng ta nạp các giá trị ban đầu cho phép ngắt và tách số BCD rồi hiển thị lên LED dùng phương pháp quét led ( nói sơ qua về phương pháp quét led cho một số bác chưa biết hiểu: chúng ta nối các chân a,b,c,d,e,f,g,dp của led chục và led đơn vị lại với nhau, và ta gửi tín hiệu ra led để hiển thị giá trị cần hiển thị và dĩ nhiên là nếu chúng ta cho phép cả hai led thì cả hai led đều hiển thị một số, cho nên trong một lúc chúng ta chỉ cho phép một led sáng.
ví dụ khi muốn hiển thị số 15 thì ta cần led chục hiển thị số 1 còn led đơn vị hiển thị số 5 vậy thì đầu tiên ta gửi tín hiệu cho sáng số 1 rồi tắt led đơn vị và cho phép led chục, delay một khoảng thời gian rồi gửi tiếp tín hiệu cho sáng số 5 rồi tắt led chục và cho phép led đơn vị)
quét led nghĩa là cho trong một trạng thái chỉ có một led được sáng cứ như thế led chục sáng số 1 và tắt led đơn vị, delay một khoảng thời gian rồi tắt led chục và cho led đơn vị sáng số 5 rồi delay một khoảng thời gian, tốc độ sáng led là khoảng 24hình/s như thế thì mắt chúng ta có không thể nhận biết được sự thay đổi đó và có cảm giác là nó đang hiển thị số 15. Giải thuật tách số đếm trong R7 như thế này: chúng ta nạp cho B một giá trị là 10 và lấy R7 chuyển vào A rồi lấy A chia cho B như thế phần nguyên sẻ nằm trong A ( tức là số chục lưu trong A ) còn phần dư nằm trong B ( tức là số đơn vị nằm trong B), như vậy là ta đã tách được số chục và số đơn vị ra, chúng ta chuyển số hàng chục ra port0 rồi cho led chục tích cực và tắt led đơn vị, rồi chuyển B và A rồi xuất nó ra port0 và cho phép led đơn vị sáng và tắt led chục.
Còn đây là code hoàn chỉnh:





ORG 0000H ; điểm vào reset
LJMP MAIN ; gọi chương trình chính
ORG 000BH ; vecter timer 0
LJMP T0_ISR ; gọi chương trình ngắt timer 0
ORG 0003H ; vecter ngắt ngoài 0
LJMP E0_ISR ; gọi chương trình ngắt ngoài 0
ORG 001BH ; vecter timer 1
LJMP T1_ISR ; gọi chương trình ngắt timer 1
ORG 0030H ; điểm vào chương trình chính
MAIN: MOV TMOD, #12H ; timer 0 chế độ 2 và timer 1 chế độ 1
MOV TH0,#(-13) ; sau 13 Ms thì xảy ra ngắt timer 0 ( tần số 38Khz)
SETB TR0 ; cho phép timer 0 chạy
SETB EA ; cho phép ngắt toàn bộ
SETB ET0 ; cho phép ngắt timer 0
SETB EX0 ; cho phép ngắt ngoài

SETB IT0 ; ngắt cạnh xuống
CLR P1.4 ; xóa p1.4 về 0 (tắt led báo hiệu dừng băng truyền)
MOV R7,#0 ; nạp cho R7 giá trị ban đầu (R7 chứa số đếm)
MOV R5,#50 ; nạp cho R5 giá trị 50 (mục đích tạo khoảng thời gian để ngừng băng truyền)
LOOP: MOV A,R7 ; chuyển số đếm trong R7 vào A
MOV B,#10 ; nạp cho B giá trị 10
DIV AB ; chia A cho B
MOV DPTR,#LUT ; chỉ con trỏ DPTR vào bảng LUT
MOVC A,@A+DPTR ;chuyển giá trị đã chọn trong bảng LUT vào thanh ghi tích lũyA
MOV P0,A ; xuất A ra port 0
CLR P1.7 ; cho phép led chục sáng
SETB P1.6 ; tắt led đơn vị
ACALL DELAY ; gọi chương trình delay
MOV A,B ; chuyển B vào A
MOV DPTR,#LUT ; chỉ con trỏ DPTR vào bảng LUT
MOVC A,@A+DPTR ;chuyển giá trị đã chọn trong bảng LUT vào thanh ghi tích lũyA
MOV P0,A ; xuất A ra port 0
CLR P1.6 ; cho phép led đơn vị sáng
SETB P1.7 ; tắt led chục
ACALL DELAY ; gọi chương trình delay
SJMP LOOP ; quay lại chương trình chính
RET

T0_ISR: CPL P1.5 ; đảo trạng thái p1.5 ( mục đích tạo xung vuông )
RETI ; quay lại từ ngắt
E0_ISR: INC R7 ; tăng R7 lên 1
CJNE R7,#20,TIEP ; so sánh R7 với 20, nếu chưa bằng thì nhảy tới nhản TIEP còn nếu bằng rồi thì gọi chương trình TIEPTUC
ACALL TIEPTUC ; gọi chương trình TIEPTUC
TIEP: CJNE R7,#40,TIEP1 ; so sánh R7 với 40
ACALL TIEPTUC ; gọi chương trình tiếp tục
TIEP1: CJNE R7,#60,TIEP2 ; so sánh R7 với 60
ACALL TIEPTUC ; gọi chương trình TIEPTUC
TIEP2: CJNE R7,#80,TIEP3 ; so sánh R7 với 80
ACALL TIEPTUC ; gọi chương trình TIEPTUC
TIEP3: CJNE R7,#100,EXIT ; so sánh R7 với 100
MOV R7,#0 ; xóa R7 về 0
ACALL TIEPTUC ; gọi chương trình TIEPTUC
EXIT: RETI ; quay về từ ngắt
DELAY: MOV R6,#200
DJNZ R6,$
RET ; 3 dòng lệnh này là delay 400Ms

TIEPTUC: SETB P1.4 ; cho đèn sáng ( báo hiệu dừng băng truyền )
SETB ET1 ; cho phép ngắt timer 1
MOV TH0,#HIGH(-50000)
MOV TL0,#LOW(-50000) ; hai dòng lệnh này là nạp giá trị cho timer 1 ( sau 50000 Ms thì xảy ra ngắt timer 1)
SETB TR1 ; cho timer 1 chạy
RET ; kết thúc chương trình tiếp tục

T1_ISR: DJNZ R5,THOAT ; giảm R5 đi 1 và so sánh nó với 0 nếu chưa bằng 0 thì thoát còn nếu bằng 0 thì lằm tiếp
CLR P1.4 ; tắt đèn ( báo hiệu cho băng truyền hoạt động trở lại )
CLR ET1 ; cấm ngắt timer 1
CLR TR1 ; dừng timer 1
MOV R5,#50 ; nạp lại cho R5 giá trị 50
THOAT: RETI ; trở về từ ngắt

LUT: DB 03H,9FH,25H,0DH,99H,49H,41H,1FH,01H,09H
END
Theo hlab.com.vn - Contact Author:kisfullc3dt1@gmail.com

24 comments:

Duy Luan said...
9/8/12

chương trình này dài quá, dùng ngắt ngoài thì ngắn hơn

Thoai Nguyen said...
4/12/12

-ở phần mạch thu ta có thể dùng giống như mạch phát dk ko bạn?
-bạn có code mạch đếm vào ra ko cho mình xin với

Chip Kool said...
5/12/12

Dạo này mình toàn bận ra xưởng....nên cũng chưa viết bài nhiều..Mạch đếm SP mình có..^^

thanh nguyen said...
30/12/12

CHIP có code C ko.cho mình xin.mình dùng đếm số người ra vào cửa.tks! :))

Havian Hoang said...
15/1/13

mình có điều này thắc mắc.Tại sao lúc bị led thu bị che khuất lại có dòng, mình nghĩ lúc đó led thu phải khoá, không dẫn chứ

Chip Kool said...
15/1/13

@Havian HoangĐêm Ôm nhiều ngày Ôm ít..bạn che mà dòng vẫn có mạnh là led thu có vẫn đề ( CDS chẳng hạn)

Havian Hoang said...
16/1/13

Cám ơn bạn nhưng ý mình hỏi đoạn này cơ: "Nguyên lý hoạt động: khi có sản phẩm đi qua thì led thu hồng ngoại bị che khuất lúc này có dòng đi từ Vcc qua led thu hồng ngoại ròi qua cực B của Q3 lúc này Q3 dẫn, cực C của Q3 xuống mức thấp lúc này tụ C4 xả điện qua diode qua Q3 và xuống mass lúc này chân số 2 của LM555 được kích và tạo ra một xung ở chân số 3 đưa về cho ic89c51 xử lý. (chân số 3 của LM555 được nối vào chân P3.2 của 89c51 tức là chân 12 )"

Mình không hiểu tại sao che mà vẫn có dòng.Mình đang phải làm 1 bài như này để làm đồ án, thấy bài của bạn rất bổ ích. Bạn giúp mình với

Cuong nguyen cao said...
6/2/13

bai nay viet dai vay? viet theo C dung ngat ngoai ngan va de hieu? hehe ...

Chip Kool said...
6/2/13

@Cuong nguyen caoThế thì bạn Cường viết 1 bài hướng dẫn các bạn làm thử xem..

Xuanhuynh Le said...
22/2/13

ANH ƠI CHO EM HỎI MẠCH TRONG MÁY ĐẾM TIỀN CŨNG DÙNG MẠCH NHƯ THE NÀY HẢ ANH????

Chip Kool said...
22/2/13

Mạch trong máy đếm tiền cơ bản là như mạch đếm sản phẩm.nhưng về cảm biến thì khac hoàn toàn vì nhận dạng tiền soi tiền và chip xử lý cho nó rất chính xác..chứ sai đếm 1 2 lần là toi rồi..:-SS

Xuanhuynh Le said...
22/2/13

ANH CÓ MẠCH ĐẾM TIỀN HAY LÀ MẠCH CẢM BIẾN TƯƠNG TỰ KO ANH GỬI LINK CHO EM THAM KHẢO ĐC KO ANH.

Xuanhuynh Le said...
22/2/13

CẢM ƠN ANH^^

Xuanhuynh Le said...
24/2/13

anh oi co ko giup em voi

Hung vo phi said...
27/2/13

bạn có boarth không cho mình xin mạch borth đc không ???

huy tran said...
21/8/13

A có đề tài mạch tương tự nào đơn giản nhưng ứng dụng vào thực tế.cao k. Cho e tham khảo duoc k a

min said...
18/9/13

a CHIP có mạch đếm sản phẩm từ 999 xuống 000 a. dùng PIC16f877a á (led hồng ngoại). anh thầy bắt làm bài tập lớn :(

việt trần said...
4/5/14

A ơi cho e xin cái mạch in luôn được không,tranviet92k1@gmail.com

Chip Kool said...
4/5/14

@min
Đếm 999 xuống 000 thì bạn sửa 1 chút là được có gì đâu..tham khảo bài viết này: http://www.chipkool.blogspot.com/2014/04/mach-dem-san-pham-hien-thi-led-7-thanh.html

Chip Kool said...
4/5/14

@việt trần Bài này do thành viên Post nhé,chip không có mạch in..muốn có phải vẽ lại

vu hong linh nguyen said...
10/11/14

A CHIP ơi! code này đầy đủ ko a? A có code hoàn chỉnh ko? cho e xin nha. Thanks a!!

Chip Kool said...
11/11/14

@vu hong linh nguyen Code bên trên đầy đủ đó bạn.

vu hong linh nguyen said...
11/11/14

thanks a! mà chuyển qua file hex dùng asm phải ko a CHIP??

Chip Kool said...
12/11/14

@vu hong linh nguyen Muốn chuyển sang file hex nạp ic cần dùng phần mềm Pinnale 52 CR nhé..^^ còn nếu dùng keil c biên dịch hex thêm dòng đầu tiên $mod51 nhé

Post a Comment

Bạn đọc hãy giúp chúng tôi xây dựng cộng đồng bằng cách để lại bình luận, chúng tôi luôn đón nhận mọi ý kiến của các bạn:
» Bình luận nghiêm túc và không chứa các liên kết quảng cáo.
» Vui lòng không Spam nhận xét với mọi hình thức.
» Rất mong bạn đề tên cho nhận xét của chính mình - Bằng cách chọn vào Tên/URL và điền tên bạn vào (Phần URL có thể bỏ trống ).

- Bạn có thể chèn Link nhạc (NCT), video(Youtube),Hình ảnh vào comment bằng cú pháp:
+ [youtube] Link video Youtube [/youtube].
+ [img] Link ảnh( định dạng PNG, JPG,GIF) [/img]
+Chèn link liên kết: <a href="LINK" rel="nofollow">Name</a>
-Bạn copy mã bên cạnh biểu tượng chèn vào nhận xét để bày tỏ cảm xúc!!

:) :( :)) :(( =)) =D> :D :P