Đèn giao thông ngã 4

Chương trình mẫu:

;*****************************************************
;Chuong trinh dieu khien den giao thong
;*****************************************************
BGIAY       EQU    R2
GIAY         EQU    R3
X1_D2        EQU    01111011B
V1_D2       EQU    10111011B
D1_X2        EQU    11011110B
D1_V2       EQU    11011101B
D1_D2       EQU    11011011B
;*****************************************************
    ORG    000H
    JMP     MAIN
    ORG    00BH
    JMP     NGAT_T0
MAIN:
    MOV    TMOD,#01H            ;T0 CHAY XUNG NOI, MODE1        
    MOV    TL0,#LOW(-50000)
    MOV    TH0,#HIGH(-50000)
    CLR     TF0
    SETB   TR0
    MOV    IE,#82H                  ;T0 DUOC PHEP NGAT KHI TRAN
    MOV    BGIAY,#0
;======================================
TD: MOV    GIAY,#10
    MOV     P0,#X1_D2
    CJNE    GIAY,#0FFH,$            ;CHO DEN X1 + V2 SANG 10s.

    MOV     P0,#V1_D2
    MOV     GIAY,#3
    CJNE    GIAY,#0FFH,$            ;CHO DEN V1 + D2 SANG 3s.

    MOV     P0,#D1_D2
    MOV     GIAY,#5
    CJNE    GIAY,#0FFH,$            ;CHO DEN D1 + D2 SANG 5 GIAY   

    MOV     P0,#D1_X2
    MOV     GIAY,#15
    CJNE    GIAY,#0FFH,$            ;CHO DEN D1 + X2 SANG 15s.

    MOV     P0,#D1_V2
    MOV     GIAY,#3            
    CJNE    GIAY,#0FFH,$            ;CHO DEN D1 + V2 SANG 3s.

    MOV     P0,#D1_D2
    MOV     GIAY,#5
    CJNE    GIAY,#0FFH,$            ;CHO DEN D1 + D2 SANG 5 GIAY
    JMP      TD
;*****************************************************
NGAT_T0:
    MOV     TL0,#LOW(-50000)
    MOV     TH0,#HIGH(-50000)
    CLR      TF0
    INC       BGIAY
    CJNE    BGIAY,#20,EXIT1       ;20  x 50ms = 1000ms = 1s
    MOV     BGIAY,#0
    DEC      GIAY
EXIT1:
RETI
END

(33kb)
Khi nhấn nút "Tải Về Máy", bạn sẽ vào trang quảng cáo, vui lòng chờ 5 giây. Nút  hiện ra ở góc phải phía trên, nhấn vào để đến trang download

Nguồn: www.sangthai.com.vn